Генерируемые файлы

[dr_Begemot]

Что надо прописать в pro-файле, чтобы файлы, генерируемые при компиляции, записывались в отдельную папку?

Имеются ввиду файлы ui_...

[TukiNov]

OBJECTS_DIR = obj/
MOC_DIR = moc/
UI_DIR = ui/

[sendevent]

OUTDIR_OS_SUFFIX = "unix"
win32 {
    OUTDIR_OS_SUFFIX = win
}
DESTDIR = release
build_pass : CONFIG(debug, debug|release){
       DESTDIR = debug
}
OBJECTS_DIR = $$DESTDIR/build_out_$$OUTDIR_OS_SUFFIX/obj
UI_DIR      = $$DESTDIR/build_out_$$OUTDIR_OS_SUFFIX/uic
RCC_DIR     = $$DESTDIR/build_out_$$OUTDIR_OS_SUFFIX/rcc
MOC_DIR     = $$DESTDIR/build_out_$$OUTDIR_OS_SUFFIX/moc

[pastor]

Код

DOS
BUILDDIR        = .build/
win32:BUILDDIR  = $$join(BUILDDIR,,,win32)
unix:BUILDDIR   = $$join(BUILDDIR,,,unix)
macx:BUILDDIR   = $$join(BUILDDIR,,,macx)
 
UI_DIR          = $${BUILDDIR}/ui
UIC_DIR         = $${BUILDDIR}/uic
MOC_DIR         = $${BUILDDIR}/moc
RCC_DIR         = $${BUILDDIR}/rcc
OBJECTS_DIR     = $${BUILDDIR}/obj
 
CONFIG(release, debug|release) {
    OBJECTS_DIR	= $$join(OBJECTS_DIR,,,/release)
}
else {
    OBJECTS_DIR	= $$join(OBJECTS_DIR,,,/debug)
}