Всем привет)
Я скачал библиотеку qwt6.0.1 из официального сайта.
Добавил в свой проект приер Spectogram. График отображается нормально, НО после добавления требует использовать вместо slots Q_SLOTS, вместо signal Q_SIGNALS. Как можно сделать так чтобы такого не было?
И иконки(icons) к кнопкам(buttons) стали не видными. В Дизайнере видит все, потом после запуска иконки не видны...
Кто нибудь с такой проблемой сталкивался?
Я думаю из за файла example.pri, там есть еще два файла qwtconfig.pri и qwtbuild.pri.
Может надо редактировать example.pri? Может там много лишнего написано?
Example.pri
QWT_ROOT = $${PWD}/..
include( $${QWT_ROOT}/qwtconfig.pri )
include( $${QWT_ROOT}/qwtbuild.pri )
TEMPLATE = app
INCLUDEPATH += $${QWT_ROOT}/src
DEPENDPATH += $${QWT_ROOT}/src
DESTDIR = $${QWT_ROOT}/examples/bin
QMAKE_RPATHDIR *= $${QWT_ROOT}/lib
contains(QWT_CONFIG, QwtFramework) {
LIBS += -F$${QWT_ROOT}/lib
}
else {
LIBS += -L$${QWT_ROOT}/lib
}
IPATH = $${INCLUDEPATH}
qtAddLibrary(qwt)
INCLUDEPATH = $${IPATH}
contains(QWT_CONFIG, QwtSvg) {
QT += svg
}
else {
DEFINES += QWT_NO_SVG
}
win32 {
contains(QWT_CONFIG, QwtDll) {
DEFINES += QT_DLL QWT_DLL
}
}qwtbuild.pri
################################################################
# Qwt Widget Library
# Copyright (C) 1997 Josef Wilgen
# Copyright (C) 2002 Uwe Rathmann
#
# This library is free software; you can redistribute it and/or
# modify it under the terms of the Qwt License, Version 1.0
################################################################
######################################################################
# qmake internal options
######################################################################
CONFIG += qt
CONFIG += warn_on
CONFIG += no_keywords
CONFIG += silent
######################################################################
# release/debug mode
######################################################################
win32 {
# On Windows you can't mix release and debug libraries.
# The designer is built in release mode. If you like to use it
# you need a release version. For your own application development you
# might need a debug version.
# Enable debug_and_release + build_all if you want to build both.
CONFIG += debug_and_release
CONFIG += build_all
}
else {
CONFIG += release
VER_MAJ = $${QWT_VER_MAJ}
VER_MIN = $${QWT_VER_MIN}
VER_PAT = $${QWT_VER_PAT}
VERSION = $${QWT_VERSION}
}
linux-g++ {
# CONFIG += separate_debug_info
}
######################################################################
# paths for building qwt
######################################################################
#MOC_DIR = moc
RCC_DIR = resources
!debug_and_release {
OBJECTS_DIR = obj
}
unix {
exists( $${QMAKE_LIBDIR_QT}/libqwt.* ) {
# On some Linux distributions the Qwt libraries are installed
# in the same directory as the Qt libraries. Unfortunately
# qmake always adds QMAKE_LIBDIR_QT at the beginning of the
# linker path, so that the installed libraries will be
# used instead of the local ones.
error( "local build will conflict with $${QMAKE_LIBDIR_QT}/libqwt.*" )
}
}
qwtconfig.pri
################################################################
# Qwt Widget Library
# Copyright (C) 1997 Josef Wilgen
# Copyright (C) 2002 Uwe Rathmann
#
# This library is free software; you can redistribute it and/or
# modify it under the terms of the Qwt License, Version 1.0
################################################################
QWT_VER_MAJ = 6
QWT_VER_MIN = 0
QWT_VER_PAT = 1
QWT_VERSION = $${QWT_VER_MAJ}.$${QWT_VER_MIN}.$${QWT_VER_PAT}
######################################################################
# Install paths
######################################################################
QWT_INSTALL_PREFIX = $$[QT_INSTALL_PREFIX]
unix {
QWT_INSTALL_PREFIX = /usr/local/qwt-$$QWT_VERSION
}
win32 {
QWT_INSTALL_PREFIX = C:/Qwt-$$QWT_VERSION
}
QWT_INSTALL_DOCS = $${QWT_INSTALL_PREFIX}/doc
QWT_INSTALL_HEADERS = $${QWT_INSTALL_PREFIX}/include
QWT_INSTALL_LIBS = $${QWT_INSTALL_PREFIX}/lib
######################################################################
# Designer plugin
######################################################################
QWT_INSTALL_PLUGINS = $${QWT_INSTALL_PREFIX}/plugins/designer
# QWT_INSTALL_PLUGINS = $${QT_INSTALL_PREFIX}/plugins/designer
######################################################################
# Features
# When building a Qwt application with qmake you might want to load
# the compiler/linker flags, that are required to build a Qwt application
# from qwt.prf. Therefore all you need to do is to add "CONFIG += qwt"
# to your project file and take care, that qwt.prf can be found by qmake.
# ( see http://doc.trolltech.com/4.7/qmake-advanced-usage.html#adding-new-configuration-features )
# I recommend not to install the Qwt features together with the
# Qt features, because you will have to reinstall the Qwt features,
# with every Qt upgrade.
######################################################################
QWT_INSTALL_FEATURES = $${QWT_INSTALL_PREFIX}/features
# QWT_INSTALL_FEATURES = $${QT_INSTALL_PREFIX}/features
######################################################################
# Build the static/shared libraries.
# If QwtDll is enabled, a shared library is built, otherwise
# it will be a static library.
######################################################################
QWT_CONFIG += QwtDll
######################################################################
# QwtPlot enables all classes, that are needed to use the QwtPlot
# widget.
######################################################################
QWT_CONFIG += QwtPlot
######################################################################
# QwtWidgets enables all classes, that are needed to use the all other
# widgets (sliders, dials, ...), beside QwtPlot.
######################################################################
QWT_CONFIG += QwtWidgets
######################################################################
# If you want to display svg images on the plot canvas, or
# export a plot to a SVG document
######################################################################
QWT_CONFIG += QwtSvg
######################################################################
# You can use the MathML renderer of the Qt solutions package to
# enable MathML support in Qwt. Because of license implications
# the ( modified ) code of the MML Widget solution is included and
# linked together with the QwtMathMLTextEngine into an own library.
# To use it you will have to add "CONFIG += qwtmathml"
# to your qmake project file.
######################################################################
QWT_CONFIG += QwtMathML
######################################################################
# If you want to build the Qwt designer plugin,
# enable the line below.
# Otherwise you have to build it from the designer directory.
######################################################################
QWT_CONFIG += QwtDesigner
######################################################################
# If you want to auto build the examples, enable the line below
# Otherwise you have to build them from the examples directory.
######################################################################
# QWT_CONFIG += QwtExamples
######################################################################
# When Qt has been built as framework qmake ( qtAddLibrary ) wants
# to link frameworks instead of regular libs
######################################################################
macx:CONFIG(qt_framework, qt_framework|qt_no_framework) {
QWT_CONFIG += QwtFramework
}
