Как добавить букву 'd' для debug версии

[Hort]

Сделал таким способой - не работает. Все время собирается с 'd' в конце.
PRO файл:

# -------------------------------------------------
# Project created by QtCreator 2009-05-09T10:08:42
# -------------------------------------------------

TEMPLATE = app
DESTDIR = ../bin

DEPENDPATH += ../tcdatabase
INCLUDEPATH += ../tcdatabase \
    $$[QT_INSTALL_PREFIX]/src/3rdparty/zlib

RESOURCES = ../resources/tceditor.qrc
SOURCES += main.cpp \
    mainwindow.cpp \
    document.cpp \
    propertiesdialog.cpp \
   questiondialog.cpp
HEADERS += mainwindow.h \
    document.h \
    propertiesdialog.h \
   questiondialog.h
FORMS += mainwindow.ui \
    document.ui \
    propertiesdialog.ui \
    questiondialog.ui

release {
    TARGET = tceditor
    LIBS += -L../lib -ltcdatabase
}
debug {
    TARGET = tceditord
    LIBS += -L../lib -ltcdatabased
}

[SABROG]

Кусок из моего проекта

Код:

CONFIG(debug, debug|release) {
    CONFIG += console
    *-g++*{
        QMAKE_CXXFLAGS_DEBUG += -pg
        QMAKE_LFLAGS_DEBUG += -pg
    }
    TARGET = $$join(TARGET,,,d)
    TMPDIR = tmp/debug
} else {
    TMPDIR = tmp/release
}
OBJECTS_DIR = $$TMPDIR
MOC_DIR = $$TMPDIR
UI_HEADERS_DIR = $$TMPDIR
RCC_DIR  = $$TMPDIR

win32:RC_FILE += ui/rs.rc

[Hort]

спасибо. а как указать LIBS, чтобы он кушал библиотеки с 'd'?

сделал так

CONFIG(debug, debug|release) {
    TARGET = $$join(TARGET,,,d)
    LIBS += -L../lib -lTcDatad
} else {
    LIBS += -L../lib -lTcData
}

но почему-то release не запускается. собирается без ошибок.
пишет:

Starting D:\Development\Qt 4\TestCrafter\bin\tceditor.exe...
D:\Development\Qt 4\TestCrafter\bin\tceditor.exe exited with code -1073741511

хотя debug запускается отлично

[SABROG]

Отладчик в руки и вперед.

[Hort]

Отладчик в руки и вперед.

под debug все нормально. а с release отладчик не запускается 

[Hort]

сорри. разобрался. все оказалось очень банально - лежали в bin старые Qt библиотеки (дебаг версии я туда не кидал)