Печать страницы - Как добавить букву 'd' для debug версии

Название: Как добавить букву 'd' для debug версии
Отправлено: Hort от Февраль 16, 2010, 13:25

Сделал таким способой - не работает. Все время собирается с 'd' в конце.
PRO файл:

Цитировать

# -------------------------------------------------
# Project created by QtCreator 2009-05-09T10:08:42
# -------------------------------------------------

TEMPLATE = app
DESTDIR = ../bin

DEPENDPATH += ../tcdatabase
INCLUDEPATH += ../tcdatabase \
$$[QT_INSTALL_PREFIX]/src/3rdparty/zlib

RESOURCES = ../resources/tceditor.qrc
SOURCES += main.cpp \
mainwindow.cpp \
document.cpp \
propertiesdialog.cpp \
questiondialog.cpp
HEADERS += mainwindow.h \
document.h \
propertiesdialog.h \
questiondialog.h
FORMS += mainwindow.ui \
document.ui \
propertiesdialog.ui \
questiondialog.ui

release {
TARGET = tceditor
LIBS += -L../lib -ltcdatabase
}
debug {
TARGET = tceditord
LIBS += -L../lib -ltcdatabased
}

Название: Re: Как добавить букву 'd' для debug версии
Отправлено: SABROG от Февраль 16, 2010, 14:28

Кусок из моего проекта

Код:

CONFIG(debug, debug|release) {
    CONFIG += console
    *-g++*{
        QMAKE_CXXFLAGS_DEBUG += -pg
        QMAKE_LFLAGS_DEBUG += -pg
    }
    TARGET = $$join(TARGET,,,d)
    TMPDIR = tmp/debug
} else {
    TMPDIR = tmp/release
}
OBJECTS_DIR = $$TMPDIR
MOC_DIR = $$TMPDIR
UI_HEADERS_DIR = $$TMPDIR
RCC_DIR  = $$TMPDIR

win32:RC_FILE += ui/rs.rc

Название: Re: Как добавить букву 'd' для debug версии
Отправлено: Hort от Февраль 16, 2010, 15:13

спасибо. а как указать LIBS, чтобы он кушал библиотеки с 'd'?

сделал так

Цитировать

CONFIG(debug, debug|release) {
TARGET = $$join(TARGET,,,d)
LIBS += -L../lib -lTcDatad
} else {
LIBS += -L../lib -lTcData
}

но почему-то release не запускается. собирается без ошибок.
пишет:

Цитировать

Starting D:\Development\Qt 4\TestCrafter\bin\tceditor.exe...
D:\Development\Qt 4\TestCrafter\bin\tceditor.exe exited with code -1073741511

хотя debug запускается отлично

Название: Re: Как добавить букву 'd' для debug версии
Отправлено: SABROG от Февраль 16, 2010, 18:24

Отладчик в руки и вперед.

Название: Re: Как добавить букву 'd' для debug версии
Отправлено: Hort от Февраль 16, 2010, 18:55

Цитата: SABROG от Февраль 16, 2010, 18:24

Отладчик в руки и вперед.

под debug все нормально. а с release отладчик не запускается :(

Название: Re: Как добавить букву 'd' для debug версии
Отправлено: Hort от Февраль 16, 2010, 19:09

сорри. разобрался. все оказалось очень банально - лежали в bin старые Qt библиотеки (дебаг версии я туда не кидал)

Russian Qt Forum

Qt => Установка, сборка, отладка, тестирование => Тема начата: Hort от Февраль 16, 2010, 13:25